home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / byt87ibm.arc / RDUNCAN.ARC / STAMPER.ASM next >
Assembly Source File  |  1987-09-27  |  16KB  |  432 lines
  1. ----------------------------------------------------------------------
  2. The MASM source file:  STAMPER.ASM
  3. ----------------------------------------------------------------------
  4.  
  5.         name    stamper
  6.         page    55,132
  7.         title   STAMPER: a simple keyboard monitor
  8.         .286c   
  9.         .sall
  10. ; 
  11. ; STAMPER.EXE: a simple OS/2 monitor that inserts
  12. ; a date or time stamp into the keyboard data stream.
  13. ;
  14. ; Alt-D  is the hot-key for a date-stamp.
  15. ; Alt-T  is the hot-key for a time-stamp.
  16. ; Alt-X  causes the STAMPER.EXE monitor to exit.
  17. ;
  18. ; Copyright (C) 1987 Ray Duncan
  19. ;
  20. ; To assemble and link this program:
  21. ;
  22. ;       MASM stamper;
  23. ;       LINK stamper,,,DOSCALLS,stamper;
  24. ;
  25. ; To use this program, execute it with the command:
  26. ;
  27. ;       C>DETACH STAMPER
  28. ;
  29.  
  30. stdin   equ     0                       ; standard device handles
  31. stdout  equ     1
  32. stderr  equ     2
  33.  
  34. cr      equ     0dh                     ; ASCII carriage return
  35. lf      equ     0ah                     ; ASCII line feed
  36.  
  37.                                         ; Hot-key definitions:
  38. datekey equ     20h                     ; Alt-D
  39. timekey equ     14h                     ; Alt-T
  40. exitkey equ     2dh                     ; Alt-X
  41.  
  42.         extrn   DOSGETINFOSEG:far       ; OS/2 API services needed
  43.         extrn   DOSEXIT:far             
  44.         extrn   DOSSLEEP:far
  45.         extrn   DOSWRITE:far
  46.         extrn   DOSMONOPEN:far          
  47.         extrn   DOSMONCLOSE:far
  48.         extrn   DOSMONREG:far
  49.         extrn   DOSMONREAD:far
  50.         extrn   DOSMONWRITE:far
  51.         extrn   VIOPOPUP:far
  52.         extrn   VIOENDPOPUP:far
  53.         extrn   VIOWRTCHARSTR:far
  54.  
  55. jerr    macro   target                  ; Macro to test return code
  56.         local   zero                    ; in AX and jump if non-zero.
  57.         or      ax,ax                   ; Uses JMP DISP16 to avoid
  58.         jz      zero                    ; branch out of range errors
  59.         jmp     target
  60. zero:
  61.         endm
  62.  
  63.  
  64. DGROUP  group   _DATA
  65.  
  66. _DATA   segment word public 'DATA'
  67.  
  68. popflag dw      1                       ; wait for PopUp window
  69. wlen    dw      ?                       ; receives length written
  70.  
  71. kname   db      '\DEV\KBD$',0           ; device name of keyboard
  72. khandle dw      0                       ; handle from DosMonOpen
  73.  
  74. gseg    dw      ?                       ; global information segment
  75. lseg    dw      ?                       ; local information segment
  76.  
  77. scrgrp  dw      ?                       ; foreground screen group 
  78.  
  79. dstr    db      'mm/dd/yy',0            ; strings used by time and
  80. tstr    db      'hh:mm',0               ; date formatting routines
  81.  
  82. monin   dw      128,64 dup (0)          ; buffers for monitor
  83. monout  dw      128,64 dup (0)
  84.  
  85. packet  db      128 dup (0)             ; buffer for kbd data packet
  86. pktlen  dw      ?                       ; length of buffer prior to read
  87.                                         ; call, length of data after.
  88.  
  89. msg1    db      cr,lf,'Start STAMPER with DETACH!',cr,lf
  90. msg1_len equ $-msg1             
  91.  
  92. msg2    db      'STAMPER utility installed!'
  93. msg2_len equ $-msg2
  94.  
  95. msg3    db      'Alt-D to insert date stamp.'
  96. msg3_len equ $-msg3
  97.  
  98. msg4    db      'Alt-T to insert time stamp.'
  99. msg4_len equ $-msg4
  100.  
  101. msg5    db      'Alt-X to shut down STAMPER.'
  102. msg5_len equ $-msg5
  103.  
  104. msg6    db      'STAMPER utility deactivated.'
  105. msg6_len equ $-msg6
  106.  
  107. msg7    db      cr,lf,'Unexpected OS/2 error',cr,lf
  108. msg7_len equ $-msg7
  109.  
  110. _DATA   ends
  111.  
  112.  
  113. _TEXT   segment word public 'CODE'
  114.  
  115.         assume  cs:_TEXT,ds:DGROUP,ss:DGROUP
  116.  
  117.  
  118. main    proc    far                     ; entry point from OS/2
  119.  
  120.         push    ds                      ; get selectors for system's
  121.         push    offset DGROUP:gseg      ; global information segments
  122.         push    ds
  123.         push    offset DGROUP:lseg
  124.         call    DOSGETINFOSEG           ; transfer to OS/2
  125.         jerr    error                   ; give up if can't get selectors
  126.  
  127.         mov     es,lseg                 ; get our screen group number
  128.         mov     ax,es:[8]               ; and make sure we are detached
  129.         cmp     ax,16
  130.         je      main1                   ; proceed, all is well
  131.  
  132.                                         ; not run with DETACH, 
  133.                                         ; display error message...
  134.         push    stderr                  ; handle for standard error
  135.         push    ds                      ; address of message
  136.         push    offset DGROUP:msg1
  137.         push    msg1_len                ; length of message
  138.         jmp     error2                  ; go display and exit
  139.  
  140. main1:  mov     es,gseg                 ; get foreground screen group 
  141.         mov     al,byte ptr es:[0018h]  ; from global info segment
  142.         cbw
  143.         mov     scrgrp,ax
  144.  
  145.                                         ; open monitor connection... 
  146.         push    ds                      ; address of name \DEV\KBD$ 
  147.         push    offset DGROUP:kname
  148.         push    ds                      ; address to receive monitor handle
  149.         push    offset DGROUP:khandle
  150.         call    DOSMONOPEN              ; transfer to OS/2
  151.         jerr    error                   ; give up if can't open it
  152.  
  153.                                         ; register as keyboard monitor...
  154.         push    khandle                 ; handle from DosMonOpen
  155.         push    ds                      ; addr of monitor input buffer
  156.         push    offset DGROUP:monin
  157.         push    ds                      ; addr of monitor output buffer
  158.         push    offset DGROUP:monout
  159.         push    1                       ; request front of list
  160.         push    scrgrp                  ; screen group we are monitoring
  161.         call    DOSMONREG               ; transfer to OS/2
  162.         jerr    error                   ; give up if can't register
  163.  
  164.         call    signon                  ; else announce our presence 
  165.  
  166. main2:                                  ; monitor the keyboard character
  167.                                         ; stream; when hot key detected,
  168.                                         ; insert the appropriate date or
  169.                                         ; time stamp, or exit.
  170.  
  171.         mov     pktlen,pktlen-packet    ; set max buffer length for read
  172.  
  173.                                         ; get next keyboard data packet
  174.         push    ds                      ; address of monitor input buffer
  175.         push    offset DGROUP:monin
  176.         push    0                       ; wait until data available
  177.         push    ds
  178.         push    offset DGROUP:packet    ; buffer for keyboard data packet
  179.         push    ds
  180.         push    offset DGROUP:pktlen    ; receives length of data packet
  181.         call    DOSMONREAD              ; transfer to OS/2
  182.  
  183.         cmp     byte ptr packet+2,0     ; is this extended code?
  184.         jnz     main4                   ; no, just pass it on
  185.  
  186.         cmp     byte ptr packet+3,exitkey
  187.         jz      main5                   ; jump if exit hot-key
  188.  
  189.         cmp     byte ptr packet+3,timekey
  190.         jnz     main3                   ; jump if not time hot-key
  191.  
  192.         cmp     word ptr packet+12,0    ; discard break packets
  193.         jnz     main2
  194.  
  195.         call    time                    ; insert the time stamp
  196.  
  197.         jmp     main2                   ; discard this key
  198.  
  199. main3:                                  ; is it datestamp hot-key?
  200.         cmp     byte ptr packet+3,datekey
  201.         jnz     main4                   ; no, jump
  202.  
  203.         cmp     word ptr packet+12,0    ; discard break packets
  204.         jnz     main2
  205.  
  206.         call    date                    ; insert the date stamp
  207.  
  208.         jmp     main2                   ; discard this key
  209.  
  210. main4:                                  ; Not hot-key, pass packet on.
  211.         push    ds                      ; address of monitor output buffer
  212.         push    offset DGROUP:monout
  213.         push    ds                      ; address of keyboard data packet
  214.         push    offset DGROUP:packet    
  215.         push    pktlen                  ; length of data packet
  216.         call    DOSMONWRITE             ; transfer to OS/2      
  217.         
  218.         jmp     main2                   ; wait for another packet
  219.  
  220. main5:                                  ; hotkey for de-install detected
  221.  
  222.         cmp     word ptr packet+12,0    ; make sure it's Break packet
  223.         jz      main2                   ; if not just discard it
  224.  
  225.         push    khandle                 ; close the monitor connection
  226.         call    DOSMONCLOSE
  227.         jerr    error
  228.  
  229.         call    signoff                 ; announce STAMPER exit 
  230.  
  231.         push    1                       ; terminate all threads
  232.         push    0                       ; return success code
  233.         call    DOSEXIT                 ; final exit to OS/2
  234.  
  235. main    endp
  236.  
  237.  
  238. error   proc    near                    ; unilateral termination 
  239.                                         ; because of unexpected error.
  240.  
  241.         cmp     khandle,0               ; first shut down monitor
  242.         je      error1                  ; if it is active
  243.         push    khandle
  244.         call    DOSMONCLOSE             ; ignore any error codes
  245.  
  246. error1:                                 ; write message 'Unexpected error'
  247.         push    stderr                  ; handle for standard error device
  248.         push    ds                      ; address of message
  249.         push    offset DGROUP:msg7
  250.         push    msg7_len                ; length of message
  251.  
  252. error2: push    ds                      ; receives bytes written
  253.         push    offset DGROUP:wlen
  254.         call    DOSWRITE                ; transfer to OS/2
  255.  
  256.         push    1                       ; terminate all threads
  257.         push    1                       ; return error code
  258.         call    DOSEXIT                 ; final exit to OS/2
  259.  
  260. error   endp
  261.  
  262.  
  263. date    proc    near                    ; format and insert date stamp
  264.  
  265.         mov     es,gseg                 ; get selector for global
  266.                                         ; read-only information segment 
  267.  
  268.         mov     al,byte ptr es:[11h]    ; convert month to ASCII
  269.         aam
  270.         add     ax,'00'
  271.         xchg    al,ah
  272.         mov     word ptr dstr,ax
  273.  
  274.         mov     al,byte ptr es:[10h]    ; convert day to ASCII
  275.         aam
  276.         add     ax,'00'
  277.         xchg    al,ah
  278.         mov     word ptr dstr+3,ax
  279.  
  280.         mov     ax,word ptr es:[12h]    ; convert year to ASCII
  281.         sub     ax,1900
  282.         aam
  283.         add     ax,'00'
  284.         xchg    al,ah
  285.         mov     word ptr dstr+6,ax
  286.  
  287.         mov     si,offset DGROUP:dstr   ; insert date stamp string
  288.         call    stuff                   ; into keyboard data stream
  289.  
  290.         ret                             ; back to caller
  291.  
  292. date    endp
  293.  
  294.  
  295. time    proc    near                    ; format and insert time stamp
  296.  
  297.         mov     es,gseg                 ; get selector for global
  298.                                         ; read-only information segment 
  299.  
  300.         mov     al,byte ptr es:[8]      ; convert hours to ASCII
  301.         aam
  302.         add     ax,'00'
  303.         xchg    al,ah
  304.         mov     word ptr tstr,ax
  305.  
  306.         mov     al,byte ptr es:[9]      ; convert minutes to ASCII
  307.         aam
  308.         add     ax,'00'
  309.         xchg    al,ah
  310.         mov     word ptr tstr+3,ax
  311.  
  312.         mov     si,offset DGROUP:tstr   ; insert time stamp string
  313.         call    stuff                   ; into keyboard data stream
  314.  
  315.         ret                             ; back to caller
  316.  
  317. time    endp
  318.  
  319.  
  320. stuff   proc    near                    ; insert string into keyboard
  321.                                         ; data stream.  Call with
  322.                                         ; SI = ASCIIZ string (null
  323.                                         ;      is discarded)
  324.                                         ; AL, SI destroyed.
  325.  
  326. stuff1: lodsb                           ; get next character
  327.         or      al,al                   ; is it null?
  328.         jnz     stuff2                  ; no, use it
  329.         ret                             ; yes, exit
  330.  
  331. stuff2: mov     packet+2,al             ; place ASCII code into packet
  332.  
  333.                                         ; now send this character
  334.                                         ; to the keyboard driver...
  335.         push    ds                      ; address of monitor output buffer
  336.         push    offset DGROUP:monout
  337.         push    ds                      ; address of keyboard data packet
  338.         push    offset DGROUP:packet    
  339.         push    pktlen                  ; length of data packet
  340.         call    DOSMONWRITE             ; transfer to OS/2
  341.         jmp     stuff1                  ; do another character  
  342.  
  343. stuff   endp
  344.  
  345.  
  346. signon  proc    near                    ; use pop-up window to 
  347.                                         ; display help message
  348.  
  349.         push    ds                      ; put up PopUp window
  350.         push    offset DGROUP:popflag   ; (wait until available)
  351.         push    0
  352.         call    VIOPOPUP
  353.  
  354.         mov     dx,offset DGROUP:msg2   ; message address
  355.         mov     cx,msg2_len             ; length
  356.         mov     ax,9                    ; Y coordinate
  357.         call    center                  ; display it
  358.  
  359.         mov     dx,offset DGROUP:msg3   ; message address
  360.         mov     cx,msg3_len             ; length
  361.         mov     ax,13                   ; Y coordinate
  362.         call    center                  ; display it
  363.  
  364.         mov     dx,offset DGROUP:msg4   ; message address
  365.         mov     cx,msg4_len             ; length
  366.         mov     ax,15                   ; Y coordinate
  367.         call    center                  ; display it
  368.  
  369.         mov     dx,offset DGROUP:msg5   ; message address
  370.         mov     cx,msg5_len             ; length
  371.         mov     ax,17                   ; Y coordinate
  372.         call    center                  ; display it
  373.  
  374.         push    0                       ; pause for 3 seconds   
  375.         push    3000                    ; (user must be quick reader!)
  376.         call    DOSSLEEP
  377.  
  378.         push    0                       ; take down PopUp window
  379.         call    VIOENDPOPUP
  380.  
  381.         ret                             ; back to caller
  382.  
  383. signon  endp
  384.  
  385.  
  386. signoff proc    near                    ; use pop-up window to
  387.                                         ; announce exit
  388.  
  389.         push    ds                      ; put up PopUp window
  390.         push    offset DGROUP:popflag   ; (wait until available)
  391.         push    0
  392.         call    VIOPOPUP
  393.  
  394.         mov     dx,offset DGROUP:msg6   ; message address
  395.         mov     cx,msg6_len             ; length
  396.         mov     ax,12                   ; Y coordinate
  397.         call    center                  ; display it
  398.  
  399.         push    0                       ; pause for 1 seconds   
  400.         push    1000                    ; (user must not blink 
  401.         call    DOSSLEEP                ;  at wrong time...)    
  402.  
  403.         push    0                       ; take down PopUp window
  404.         call    VIOENDPOPUP
  405.  
  406.         ret                             ; back to caller
  407.  
  408. signoff endp
  409.  
  410.  
  411. center  proc    near                    ; center a message on screen
  412.                                         ; call DX = msg offset,
  413.                                         ; CX = length, AX = Y coordinate
  414.  
  415.         push    ds                      ; address of message
  416.         push    dx
  417.         push    cx                      ; length of message
  418.         push    ax                      ; Y
  419.         sub     cx,80                   ; X=((80-length)/2)
  420.         neg     cx
  421.         shr     cx,1
  422.         push    cx
  423.         push    0                       ; VIO handle
  424.         call    VIOWRTCHARSTR           ; transfer to OS/2
  425.         ret                             ; back to caller
  426.  
  427. center  endp
  428.  
  429. _TEXT   ends
  430.  
  431.         end     main
  432.